レターや残り時間は箱の上にフローティングテキストで表示しますが、テクスチャで表示するように改造してボード型にするとLucky boardのようになります。更にタッチを調べる部分をsitに変えて椅子を付けたらLucky chairのような装置になります。更に更に、椅子をトイレに変えたら。。。って、もういいですかねｗｗｗ
// Lucky object
integer interval=5; // レターチェンジ間隔（分）
integer time; // 残り時間用
string letter="-?ABCDEFGHIJKLMNOPQRSTUVWXYZ"; // ラッキーレターに使う文字
string ll; // ラッキーレター用
string tmp; // 前回のレター記憶用
string prize;
win(key id, string name)
{ // 当たったときの処理
llSay(0,name+", you win!!"); // 当たりー♪
llGiveInventory(id,prize); // アイテムを渡す
init(); // initへ
}
init()
{
llSetText("OFF",<1,1,1>,1.0);
prize=llGetInventoryName(INVENTORY_OBJECT,0); // コンテンツ内の１つ目のオブジェクト名
ll=""; // レターをクリア
time=0; // 残り時間を0に設定
if (prize) llSetTimerEvent(0.1); // 賞品が入ってたら0.1秒後にタイマー
else llSetTimerEvent(0); // 入ってなかったらタイマー停止
}
default
{
state_entry()
{
init(); // initへ
}
changed(integer change)
{
if (change & CHANGED_INVENTORY) { // コンテンツ内が変化したらinit
init();
}
}
touch_start(integer total_number)
{
if (ll == "") return; // レターが設定されてないときはリターン
key id=llDetectedKey(0); // タッチしたアバターのキー
if (id == "" || id == NULL_KEY) return; // キーが取得できなかったらリターン
string name=llDetectedName(0); // タッチしたアバターの名前
if (ll == "?") win(id,name); // ラッキーレターが？だったら当たり
else {
string s=llGetSubString(name,0,0); // アバター名の最初の１文字
integer num=FALSE;
if (s == "0" || (integer)s > 0) num=TRUE; // 文字が数字かをチェック
if (ll == llToUpper(s)) win(id,name); // 文字を大文字に変換してラッキーレターと一致したら当たり
else if (ll == "0-9" && num) win(id,name); // 文字が数字でラッキーレターが0-9だったら当たり
else llSay(0,"Sorry, your name begins with "+s+"."); // それ以外はハズレ；；
}
}
timer()
{
llSetTimerEvent(60); // タイマーを60秒にセット
if (time < 1) { // 残り時間が１以下になったらレター変更
time=interval; // 残り時間を再設定
if (ll == "") ll=tmp;
while (tmp == ll) { // 前回出たレターと被らないように
integer i=llFloor(llFrand(llStringLength(letter))); // 乱数
ll=llGetSubString(letter,i,i); // 乱数からラッキーレターを決定
if (ll == "-") ll="0-9"; // レターが-だったら 0-9にする
}
tmp=ll; // 今回出たラッキーレターを記憶
llSay(0,"The lucky letter is "+ll+"."); // チャット表示
}
// フローティング表示
llSetText("If your name begins with "+ll+",\ntouch to get a prize!\n"+(string)time+" minute(s) left.",<1,1,1>,1.0);
time--; // 残り時間を減算
}
}
// Multi TP-board
integer col=3; // 横の分割数
integer row=2; // 縦の分割数
list tp=[ // "テレポート先","SIM名",位置,
"Mansion Mall","Graybar",<228,179,30>,
"Market Beach Mall East","Triasm",<242,137,21>,
"SUNSET SHOPPING MALL","JapanSeychellesLand",<72,70,23>,
"SL-Shopping.net-Mall-Jiminy","Jiminy",<115,23,106>,
"+*+*BELLE ROSE*+*+","Artsebarsky",<236,184,22>,
NULL_KEY]; // データの最後のカンマ用
integer len;
string slurl(integer i)
{ // SLURL生成
vector v=llList2Vector(tp,i+2);
string str=llList2String(tp,i);
// SIM名をブランクにしてるものは閉店表示
if (llList2String(tp,i+1) == "") return str+"... closed\n";
str+=" http://slurl.com/secondlife/";
str+=llEscapeURL(llList2String(tp,i+1));
str+="/"+(string)((integer)v.x);
str+="/"+(string)((integer)v.y);
str+="/"+(string)((integer)v.z)+" \n";
return str;
}
map(integer num)
{ // マップ表示用
integer i=num*3;
if (i >= len) { // テレポートの登録数が少ないとき
llWhisper(0,"This area is a blank.");
return; // リターン
}
string sim=llList2String(tp,i+1);
vector pos=llList2Vector(tp,i+2);
if (sim) llMapDestination(sim,pos,ZERO_VECTOR); // マップ表示
llWhisper(0,slurl(i)); // SLURL表示
}
default
{
state_entry()
{
len=llGetListLength(tp)-1; // ヌルキーを除いたリストの長さ
}
touch_start(integer total_number)
{
integer i=llDetectedTouchFace(0); // タッチした面の番号を取得
if (i != -1) { // SLビューワーが対応のとき
vector v=llDetectedTouchST(0); // タッチした表面の座標
i=llFloor(v.x*col)+(row-llCeil(v.y*row))*col; // 座標を番号に変換
map(i); // mapへ
}
else { // SLビューワーが非対応だったらSLURLを全部表示
string str="Open the chat histry and click the SLURL.\n";
for (i=0; i < len; i+=3) str+=slurl(i);
llWhisper(0,str); // チャットでSLURL表示
}
}
}
// Group gift giver
string gift;
init()
{ // コンテンツ内にあるオブジェクト名を取得
gift=llGetInventoryName(INVENTORY_OBJECT,0);
}
default
{
state_entry()
{
init(); // 最初はinit
}
changed(integer change)
{
if (change & CHANGED_INVENTORY)
{ // コンテンツ内が変化したらinitへ
init();
}
}
touch_start(integer total_number)
{
key id=llDetectedKey(0); // タッチしたアバターのキー
if (llList2Key(llGetObjectDetails(llGetKey(),[OBJECT_GROUP]),0) == NULL_KEY) {
// グループ設定されてなかったら
llWhisper(0,"Sorry, owner must set a group."); // エラーメッセージ
return; // リターン
}
else if (llGetInventoryType(gift) == INVENTORY_NONE) {
// ギフトが入ってなかったら
llWhisper(0,"Sorry, I have not a gift now."); // エラーメッセージ
return; // リターン
}
if (llSameGroup(id)) { // グループが一致したら
llGiveInventory(id,gift); // ギフトを渡す
llInstantMessage(id,"Here is an our group gift, thanks."); // グループギフトをどうぞ～♪
}
else { // 一致しなかったらエラーメッセージ
llInstantMessage(id,"Group member only. Activate our group tag and touch again.");
}
}
}
#!/usr/bin/env python
import sys,re,datetime
if len(sys.argv) <= 1:
print "Usage: "+sys.argv[0]+" filename"
else:
s="dummy"
text=""
f=open(sys.argv[1])
while s != "":
s=f.readline()
m=re.match("(^DATE: )(\d{2}/\d{2}/\d{4} \d{2}:\d{2}:\d{2})(\r{0,1}\n{0,1}$)",s)
if m:
data=m.group(2)
dt=datetime.datetime.strptime(data,"%m/%d/%Y %H:%M:%S")
dt=dt+datetime.timedelta(hours=-9)
data=dt.strftime("%m/%d/%Y %I:%M:%S %p")
s=m.group(1)+data+m.group(3)
text+=s
f.close()
new="conv_"+sys.argv[1]
f=open(new,"w")
f.write(text)
f.close()
print "Saved to "+new
Second Lifeというメタバース内でスクリプト製品、家具、その他雑貨などのアイテムを製作販売してます。宜しくお願いします＾＾
旧ブログで書いてた過去記事は放置かも - SHOP CHIHIRO (backup)に保存してます。
掲載してるスクリプトは自由にご利用ください＾＾ 但し、一応全部自作なので著作権は発生すると思います。なのでオープンソースで配布や掲載などされるときは、載せてる記事へのリンク貼るとか、私が作者だとわかるような表示をお願いしますね＾＾
You may use published scripts on this blog, but I have those copyright. When publish, opensourced redistribution or resale them, must link to a my page of that published script or retain the copyright notice by including 'Written by Chihiro Owatatsumi' in the source code.